IF setconsole("hide")
  ENDIF
;
;     NT/95 collect outlook information - Kixtart 3.63, 4.00
;
; (c) scripting@wanadoo.nl 2001
;
;     vs 1.03 - program
;
;     1.00p (20010525)     original version
;     1.01p (20010701)     - minor fix to incorrect substr specification
;     1.02  (20010701)     - minor change to kix script
;     1.03p (20010710)     - standardization of $info_file value
;
  $prgrm_version="1.03"
  ;
  $tmp_directory=ExpandEnvironmentVars("%tmp%")
  IF (substr($tmp_directory,len($tmp_directory),1) = "\")
    $tmp_directory=substr($tmp_directory,1,len($tmp_directory)-1)
  ENDIF

; --------------------------------------------------------------------------
; -                                                                        -
; --------------------------------------------------------------------------

  $info_file=$tmp_directory+"\Outlook.lst"

; --------------------------------------------------------------------------
; -                                                                        -
; --------------------------------------------------------------------------

  del $info_file
  IF (RedirectOutput($info_file) <> 0)
  ENDIF

  $number_of_outlook_keys=22
  DIM $outlook_keys[$number_of_outlook_keys+1]
  $outlook_keys[01]="001e023d" ; "Microsoft Outlook.FAV"
  $outlook_keys[02]="001e0324" ; "u:\\My Documents\\archive.pst"
  $outlook_keys[03]="001e0336" ; "IPF.Appointment"
  $outlook_keys[04]="001e03e8" ; "u:\\My Documents\\Microsoft Outlook.SCD"
  $outlook_keys[05]="001e3001" ; "Our Kixtart"
  ;        "MS Exchange Hook"
  ;        "Mailbox - Our Kixtart"
  ;        "Microsoft Exchange Directory Service"
  ;        "Microsoft Exchange Remote Transport"
  ;        "Microsoft Exchange Server"
  ;        "Microsoft Exchange Transport"
  ;        "Outlook Address Book"
  ;        "Personal Address Book"
  ;        "Personal Folders"
  ;        "Public Folders"
  $outlook_keys[06]="001e3004" ; ""
  $outlook_keys[07]="001e3006" ; "MS Exchange Hook"
  ;        "Microsoft Exchange Directory Service"
  ;        "Microsoft Exchange Remote Transport"
  ;        "Microsoft Exchange Server"
  ;        "Microsoft Exchange Transport"
  ;        "Outlook Address Book"
  ;        "Personal Address Book"
  ;        "Personal Folders"
  $outlook_keys[08]="001e300a" ; "EMSABP.DLL"/"EMSMDB.DLL"/"EMSUI.DLL"/"MSPST.DLL"/"contab.dll"/"mspst.dll"
  $outlook_keys[09]="001e3d09" ; "CONTAB"/"MSEMS"/"MSPST AB"/"MSPST MS"
  $outlook_keys[10]="001e3d0a" ; "MSPST.DLL"/"contab.dll"/"emsui.dll"/"mspst.dll"
  $outlook_keys[11]="001e3d0b" ; "EMSCfg"
  ;        "PABServiceEntry"
  ;        "PSTServiceEntry"
  ;        "ServiceEntry"
  $outlook_keys[12]="001e6600" ; "p:\OurKixtart.pab"
  ;        "c:\windows\mailbox.pab"
  $outlook_keys[13]="001e6602" ; "SERVER01"
  $outlook_keys[14]="001e6603" ; "/o=Kix Test Bed/ou=DONCASTER/cn=Recipients/cn=OKixtart"
  $outlook_keys[15]="001e6607" ; "Our Kixtart"
  $outlook_keys[16]="001e660b" ; "/o=Kix Test Bed/ou=DONCASTER/cn=Recipients/cn=OKixtart"
  $outlook_keys[17]="001e660c" ; "SERVER01"
  $outlook_keys[18]="001e6612" ; "/o=Kix Test Bed/ou=DONCASTER/cn=Configuration/cn=Servers/cn=SERVER01"
  $outlook_keys[19]="001e6614" ; "/o=Kix Test Bed/ou=DONCASTER/cn=Configuration/cn=Servers/cn=SERVER01"
  $outlook_keys[20]="001e6700" ; "C:\\WINDOWS\\outlook.pst"
  $outlook_keys[21]="001e6750" ; "Outlook"
  $outlook_keys[22]="00033009" ; "00,00,00,00"/"02,10,00,00"/"04,00,00,00"/"06,10,00,00"
  ;"DefaultProfile"="Outlook"

; --------------------------------------------------------------------------

  ; HKCU\Software\Microsoft<\Windows NT\CurrentVersion>\Windows Messaging Subsystem\Profiles\<default_profile>\<subkey>+[key:value]
  ;
  ; variables:
  ; 1. <\Windows NT\CurrentVersion>  (= additional structure for NT/W2K)
  ; 2. <default_profile>             (f.e. Outlook Express, Microsoft Outlook)
  ; 3. <subkey>+[key:value]          (.f.e 315ddf5559e26e42bdc725be09fba714)

  $search_location="HKEY_CURRENT_USER\Software\Microsoft\Windows Messaging Subsystem\Profiles"
  IF (ExistKey($search_location) <> 0)
    $search_location="HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\Windows Messaging Subsystem\Profiles"
    IF (ExistKey($search_location) <> 0)
      GOSUB error_message
      EXIT
    ENDIF
  ENDIF
  IF (ExistKey($search_location) <> 0)
    GOSUB error_message
    EXIT
  ENDIF

  ; search      location+<subkey>+[key:value]

; --------------------------------------------------------------------------
; -                                                                        -
; --------------------------------------------------------------------------

  ?
  ? "Outlook Information          (inc.all profiles "+$prgrm_version+" - kix "+@kix+")"
  ?
  IF (ExistKey($search_location) = 0)
    ? "input  -> ["+$search_location+"]"
    ?
    $index1=0
    DO
      $profile=ENUMKEY($search_location, $index1)
      IF (len($profile) <> 0)
        $ikey=$search_location+"\"+$profile
        IF (ExistKey($ikey) = 0)
          IF (LCASE(ReadValue($search_location,"DefaultProfile")) = LCASE($profile))
            ? "profile > ["+$profile+"] (DefaultProfile)"
          ELSE
            ? "profile > ["+$profile+"]"
          ENDIF
          $index2=0
          DO
            $isub_key=ENUMKEY($ikey, $index2)
            ? "          "+$ikey+"\"+$isub_key
            IF (len($isub_key) <> 0)
              $index3=1
              DO
                $outlook_key=$outlook_keys[$index3]
                $ivalue3=ReadValue($ikey+"\"+$isub_key, $outlook_key)
                IF (len($ivalue3) <> 0)
                  SELECT
                  CASE ($outlook_key = "001e0324") ; "U:\My Documents\Archive.pst"
                    ? "               ["+$outlook_key+"]="+$ivalue3+" ("+GetFileSize($ivalue3)+" Bytes)"
                  CASE ($outlook_key = "001e03e8") ; "U:\My Documents\Microsoft Outlook.SCD"
                    ? "               ["+$outlook_key+"]="+$ivalue3+" ("+GetFileSize($ivalue3)+" Bytes)"
                  CASE ($outlook_key = "001e6600") ; "U:\My Documents\Mailbox.pab"
                    ? "               ["+$outlook_key+"]="+$ivalue3+" ("+GetFileSize($ivalue3)+" Bytes)"
                  CASE ($outlook_key = "001e6700") ; "U:\My Documents\Outlook.pst"
                    ? "               ["+$outlook_key+"]="+$ivalue3+" ("+GetFileSize($ivalue3)+" Bytes)"
                  CASE 1
                    ? "               ["+$outlook_key+"]="+$ivalue3
                  ENDSELECT
                ENDIF
                $index3=$index3+1
              UNTIL ($index3 > $number_of_outlook_keys)
            ENDIF
            $index2=$index2+1
          UNTIL (len($isub_key) = 0)
        ENDIF
      ENDIF
      $index1=$index1+1
    UNTIL (len($profile) = 0)
  ENDIF
  ?
  ? "completed"
  ?
  IF (RedirectOutput("") <> 0)
  ENDIF
  ? "Informative Outlook: output written to file '"+$info_file+"'."